Request for a script!

[Mangler]

So... I have a terrible memory. And people keep talking to me like they think I know who they are. I don't. Because even if you've told me... I can't remember. I basically can only identify Lykan because he plays all his alts the same. And Eviscerator because he won't shut up. And Tarn because he keeps telling me over and over who he is. We like Tarn.

SOOOOO... who can write a script where I can link people together, so that if I WHOIS XXX, it tells me all their alts that I have tagged?

[Perdue]

Zmud or Cmud?

[Mangler]

Zmud sorry, should have said.

[Naerin]

Here you go!

#CLASS {AltTagging}
#TRIGGER {whois %1} {#ECHO You have %1 tagged as: Austin}
#CLASS 0

[Mangler]

I'm clever. That's just going to tell me everyone is Austin! Isn't it?

[toribio]

It wont be wrong, everyone is Austin

[Taziar]

I can write one after work tonight if some else doesn't make you one before then.

[Taziar]

Took me long enough... got stuck on one issue for hours and hours (over two days) and when I finally brainstormed a work around it took 5 mins. Hahaha.

Also posting on my House of Medakan thread @ wotmudarchives.org forums in the zmud section.

-----Alt Tracker Commands-----

type helpAltTracker to see help file

type altAdd <mainName> <altName> to add an alt name to character name file.
--Example: type altAdd Austin Kirtha to add Kirtha to Austin's alt file.

type altNames for a list of all current characters and alts on file.

type whois <name> as normal, if that character has an alt you know it will display it.

type altRemove <name> to remove a character name from the file.

Code: Select all

#CLASS {AltTracker}
#ALIAS helpAltTracker {
	#SHOW {""}
	#SHOW {""}
	#SHOW {"-----Alt Tracker Commands-----"}
	#SHOW {""}
	#SHOW {"type altAdd <mainName> <altName> to add an alt name to character name file."}
	#SHOW {"--Example: type altAdd Austin Kirtha to add Kirtha to Austin's alt file."}
	#SHOW {""}
	#SHOW {"type altNames for a list of all current characters and alts on file."}
	#SHOW {""}
	#SHOW {"type whois <name> as normal, if that character has an alt you know it will display it."}
	#SHOW {""}
	#SHOW {"type altRemove <name> to remove a character name from the file."}
	#SHOW {""}
	}
#ALIAS altAdd {
	#IF (%ismember(%proper(%1),@altCharName)) {#SHOW {""}} {
			#ADDITEM altCharName %proper(%1)
			#VAR %concat("alt",%proper(%1)) {} {_nodef} "AltTracker|AltFiles"
			#SHOW {""}
			#ECHO {%proper(%1) was added to the main character file.}
			}
	#IF (%ismember(%proper(%2),@altCharAlt)) {
		#ECHO {%proper(%2) is already a listed alt of a main character.}
		} {#IF (%len(%2) > 1) {#ADDITEM altCharAlt %proper(%2)}
			#IF (%len(%2) > 1) {#ADDITEM %concat("alt",%proper(%1)) %proper(%2)}
			#IF (%len(%2) > 1) {#ECHO {%proper(%2) is now an alt of %proper(%1).}}
			}
	}
#ALIAS altNames {
	#SHOW {""}
	#SHOW {""}
	#FORALL @altCharName {
		#VAR altNameLoop {%concat(~@,alt,%i)}
		#SHOW {%i "--->" @altNameLoop}
		}
	}
#ALIAS altRemove {
	#SHOW {""}
	#IF (%ismember(%proper(%1),@altCharName)) {
		#DELITEM altCharName %proper(%1)
		#UNVAR %concat("alt",%proper(%1)) "AltTracker|AltFiles"
		#ECHO {%proper(%1) was removed from the main character file.}
		}
	#IF (%ismember(%proper(%1),@altCharAlt)) {
		#DELITEM altCharAlt %proper(%1)
		#ECHO {%proper(%1) was removed from the alt character file.}
		}
	#FORALL @altCharName {
		#DELITEM %concat("alt",%i) %proper(%1)
		#DELITEM %concat("alt",%i) %null
		}
	}
#ALIAS altWhois {
	#IF (%ismember(%proper(@altNameWhois),@altCharName)) {
		#VAR altNameWho %concat(~@,alt,@altNameWhois)
		#ALARM +1 {
			#SHOW {""}
			#ECHO {Known alts: @altNameWho}
			}
		}
	#IF (%ismember(%proper(@altNameWhois),@altCharAlt)) {
		altWhoMain
		}
	}
#ALIAS altWhoMain {
	#FORALL @altCharName {
		#ADDITEM altNameFind {%concat(~@,alt,%i)}
		#VAR altNameFindLiteral {%concat(~"~@,alt,%i~")}
		#IF (%ismember(%proper(@altNameWhois),@altNameFind)) {
			#ALARM +1 {
				#SHOW {""}
				#ECHO {%proper(@altNameWhois) is an alt of %remove("@alt",@altNameFindLiteral).}
				#VAR altNameFind {}
				}
			#ABORT 1
			}
		#DELITEM altNameFind {%concat(~@,alt,%i)}
		}
	}
#ONINPUT {whois &%waltNameWhois} {
	altWhois
	}
#VAR altNameLoop {}
#VAR altNameWho {}
#VAR altNameWhois {}
#VAR altNameFind {}
#VAR altNameFindLiteral {}
#CLASS 0
#CLASS {AltTracker|AltFiles}
#VAR altCharName {}
#VAR altCharAlt {}
#CLASS 0

[Mangler]

Thanks! Not had chance to use it yet but much appreciated all the same

[Elysia]

Mangler, you can add me under "Kirtha".